#name 月·如影随行紫霞宏_v0.21
#hello 欢迎$name测试“月·如影随行紫霞宏”
#tip v0.2版优化输出循环与破苍穹释放时机判断
#icon 2763
#delay 1
#varbool v_自动扶摇,icon:1485
#varnum v_爆发模式,3,tip:爆发模式_右键菜单,tip_1:只有目标是BOSS才爆发,tip_2:对所有目标都爆发,tip_3:关闭,icon_1:2129,icon_2:2145,icon_3:3597
#varbool v_自动打断,icon:1441
#varbool v_目标选择,tip:自动切换目标,icon:3115
#varbool v_自动腰坠,tip:特效腰坠,tip_1:自动,tip_2:手动,icon:2835
#skillbox 抱元守缺,凭虚御风,九转归一,破苍穹,镇山河:off

--非战斗状态判断，避免在忘记关宏的情况下误开BOSS，若嫌多余影响战斗节奏可将下行语句删除。
/return [nofight]
/if [lastota:四象轮回]
	/var [nav+3] v_nav
/else
	/if [lastcast:太极无极;buff:韬光养晦]
		/var [nav+1] v_nav
	/else
		/var [nav] v_nav
	/end
/end

--------------------------------副本躲避--------------------------------

/skill QTE
/cbuff [tpre:云烟卷] 弹跳
/skill [mapc:战宝军械库,tar:卓力格图,tpre:掷锤>0.5,nobuff:镇山河] 打断,后撤
/skill [mapc:战宝军械库,tar:澹台枯火,tpre:骨牢>0.5,nobuff:镇山河] 打断,后撤
/skill [mapc:战宝军械库,tar:萧沙,dis<10;tar:澹台枯火,dis<5] 扶摇直上
/skill [mapc:大明宫,tar:何莘涯,tpre:力拔千钧>0.7|吞云吐纳>0.7,nobuff:镇山河,tmfront,dis<10] 打断,后撤
/skill [mapc:大明宫,tar:安禄山,ftime>10,(tlife>0.7;tlife<0.12)] 扶摇直上
/skill [buff:沙暴|火星|内伤;tar:独孤问俗,tlife<0.1;tbuff:白昼;tar:李倓,tlife>0.2;tar:沙叱博,tlife<0.4] 扶摇直上
/skill [tpre:皇之怒|狼之怒|藏离精失|九鼎天怒式,nocd:扶摇直上] 打断,扶摇直上
/skill [!banskill:镇山河,tpre:皇之怒,cd:扶摇直上] 清空目标,镇山河
/skill [map:英雄华清宫,target:葛尔东赞,tprepare:风卷残云>0.8] 迎风回浪
/if [v_自动扶摇]
	/skill [nocd:扶摇直上] 扶摇直上
/end

----------------------------减伤、保命、回蓝-----------------------------

/skill [fight,noota,life<=0.8,nobuff:坐忘无我|渊|镇山河|春泥护花|圣手织天|蝶戏水|风袖低昂|舍身,sktest:坐忘无我] 坐忘无我
/skill [fight,noota,(nobuff:九襄地玄五阵|金刚伏魔五阵|引羌笛|极乐;threat>0.8),!banskill:凭虚御风,sktest:凭虚御风] 凭虚御风
/skill [fight,noota,life<0.6,distance<8,notar:黑色傀儡,!banskill:九转归一] 九转归一
/if [fight,!banskill:镇山河,notar:伊玛目|安禄山,life<=0.2,sktest:镇山河,nobuff:春泥护花|圣手织天|镇山河|风袖低昂|舍身]
	/skill 保存目标
	/skill 清空目标,镇山河
	/skill 读取目标
/end
/inter [noota,nobuff:蛊时,gcd>1,(mana<0.8;life<0.8)] 仙王蛊鼎
/skill [noota,nav>=8,mana<=0.5,nocd:抱元守缺,!banskill:抱元守缺,nobuff:紫气东来&玉清玄明&赤霄红莲] 抱元守缺

--------------------------------自动打断-------------------------------

/var [tpre:护体|上品金创药|库尔达祷言|天音化物|雨钓江秋|无懈可击|火舞金刚|疯狂之怒|净与无净|吸取内力|再生|尸吼功|毒藤手|噬血影|一阳指·二品|龙甩尾|阴阳双流|急行军|骑军令|绞喉|怒吼>0] v_目标运功
/skill [v_自动打断,sklv:八卦洞玄=1,sktest:八卦洞玄,v_目标运功] 打断,八卦洞玄

------------------------------自动切换目标------------------------------

/if [fight,v_目标选择,mapc:大明宫]
	/if [existnpc:乾坤剑意,notar:乾坤剑意;tar:乾坤剑意,tlife<0.1]
		/tab [tar:乾坤剑意,tlife>0.1] npc
	/end
	/if [existnpc:维提吠达特天罚剑,notar:维提吠达特天罚剑;tar:维提吠达特天罚剑,tlife<0.1]
		/tab [tar:维提吠达特天罚剑,tlife>0.1] npc
	/end
/skill [tar:伊玛目,existnpc:袄教使者,tlife<=0.4,nocd:生太极] 生太极
/end

------------------------------破苍穹与爆发------------------------------

/if [!banskill:破苍穹,(aurotime:破苍穹<2;nobuff:破苍穹),nav<7,nobuff:紫气东来&韬光养晦&玉清玄明&赤霄红莲]
	/skill 保存目标,破苍穹
	/skill [ota:破苍穹] 自身目标
/end
/skill [noota,lastota:破苍穹;notar] 读取目标
/if [fight,(v_爆发模式=1,(tar:boss;tname:木桩);v_爆发模式=2),noota]
	/skill [nav>7,mana>0.3,aurotime:破苍穹>=12] 紫气东来
	/skill [nav<6,aurotime:破苍穹>=15] 韬光养晦
	/skill [v_自动腰坠,buff:紫气东来] 腰坠
/end

--------------------------------输出循环--------------------------------

/skill [sktest:两仪化形,buff:玉清玄明|赤霄红莲] 两仪化形
/if [state:stand]
	/skill [sktest:太极无极,v_nav=6,noota,(nocd:万世不竭;cdtime:万世不竭<1.44),nobuff:韬光养晦&紫气东来] 太极无极
	/skill [sktest:万世不竭,v_nav>=8,(ota:四象轮回<0.2;noota)] 打断,万世不竭
	/return [ota:万世不竭]
	/skill [sktest:两仪化形,cdtime:万世不竭>=1.44,v_nav>9] 两仪化形
	/skill [sktest:两仪化形,buff:韬光养晦&紫气东来,v_nav>6] 两仪化形
	/skill [v_nav<9,noota;dis>20] 四象轮回
/elseif [state:run|jump]
	/skill [sktest:两仪化形,(v_nav>=8;buff:韬光养晦,v_nav>=5)] 两仪化形
	/skill [sktest:太极无极] 太极无极
/end
#net http://www.yylmacro.com/cloud/17862